Version: 4.2.1

14.3 Linking Units

We can make our toy economy more efficient by having toy factories that cooperate with stores, creating toys that do not have to be repainted. Instead, the toys are always created using the store’s color, which the factory gets by importing toy-store^:

  ; In "store-specific-factory-unit.ss":
  #lang scheme
  
  (require "toy-factory-sig.ss")
  
  (define-unit store-specific-factory@
    (import toy-store^)
    (export toy-factory^)
  
    (define-struct toy () #:transparent)
  
    (define (toy-color t) (store-color))
  
    (define (build-toys n)
      (for/list ([i (in-range n)])
        (make-toy)))
  
    (define (repaint t col)
      (error "cannot repaint")))
  
  (provide store-specific-factory@)

To invoke store-specific-factory@, we need toy-store^ bindings to supply to the unit. But to get toy-store^ bindings by invoking toy-store@, we will need a toy factory! The unit implementations are mutually dependent, and we cannot invoke either before the other.

The solution is to link the units together, and then we can invoke the combined units. The define-compound-unit/infer form links any number of units to form a combined unit. It can propagate imports and exports from the linked units, and it can satisfy each unit’s imports using the exports of other linked units.

  > (require "store-specific-factory-unit.ss")
  > (define-compound-unit/infer toy-store+factory@
      (import)
      (export toy-factory^ toy-store^)
      (link store-specific-factory@
            toy-store@))

The overall result above is a unit toy-store+factory@ that exports both toy-factory^ and toy-store^. The connection between store-specific-factory@ and toy-store@ is inferred from the signatures that each imports and exports.

This unit has no imports, so we can always invoke it:

  > (define-values/invoke-unit/infer toy-store+factory@)
  > (stock! 2)
  > (get-inventory)

  (#(struct:toy) #(struct:toy))

  > (map toy-color (get-inventory))

  (green green)