On this page:
7.6.1 Contracts and eq?
7.6.2 Defining recursive contracts
7.6.3 Using set! to Assign to Variables Provided via provide/ contract
Version: 4.2.1

7.6 Gotchas

7.6.1 Contracts and eq?

As a general rule, adding a contract to a program should either leave the behavior of the program unchanged, or should signal a contract violation. And this is almost true for PLT Scheme contracts, with one exception: eq?.

The eq? procedure is designed to be fast and does not provide much in the way of guarantees, except that if it returns true, it means that the two values behave identically in all respects. Internally, this is implemented as pointer equality at a low-level so it exposes information about how PLT Scheme is implemented (and how contracts are implemented).

Contracts interact poorly with eq? because function contract checking is implemented internally as wrapper functions. For example, consider this module:
  #lang scheme
  
  (define (make-adder x)
    (if (= 1 x)
        add1
        (lambda (y) (+ x 1))))
  (provide/contract [make-adder (-> number? (-> number? number?))])

It exports the make-adder function that is the usual curried addition function, except that it returns Scheme’s add1 when its input is 1.

You might expect that
  (eq? (make-adder 1)
       (make-adder 1))

would return #t, but it does not. If the contract were changed to any/c (or even (-> number? any/c)), then the eq? call would return #t.

Moral: do not use eq? on values that have contracts.

7.6.2 Defining recursive contracts

When defining a self-referential contract, it is natural to use define. For example, one might try to write a contract on streams like this:

  > (define stream/c
     (promise/c
      (or/c
       null?
       (cons/c number? stream/c))))

  reference to undefined identifier: stream/c

Unfortunately, this does not work because the value of stream/c is needed before it is defined. Put another way, all of the combinators evaluate their arguments eagerly, even thought the values that they accept do not.

Instead, use
  (define stream/c
   (promise/c
    (or/c
     null?
     (cons/c 1
             (recursive-contract stream/c)))))

The use of recursive-contract delays the evaluation of the identifier stream/c until after the contract is first checked, long enough to ensure that stream/c is defined.

See also Checking Properties of Data Structures.

7.6.3 Using set! to Assign to Variables Provided via provide/contract

The contract library assumes that variables exported via provide/contract are not assigned to, but does not enforce it. Accordingly, if you try to set! those variables, you may be surprised. Consider the following example:

  > (module server scheme
      (define (inc-x!) (set! x (+ x 1)))
      (define x 0)
      (provide/contract [inc-x! (-> void?)]
                        [x integer?]))
  > (module client scheme
      (require 'server)
    
      (define (print-latest) (printf "x is ~s\n" x))
    
      (print-latest)
      (inc-x!)
      (print-latest))
  > (require 'client)

  x is 0

  x is 0

Both calls to print-latest print 0, even though the value of x has been incremented (and the change is visible inside the module x).

To work around this, export accessor functions, rather than exporting the variable directly, like this:

  #lang scheme
  
  (define (get-x) x)
  (define (inc-x!) (set! x (+ x 1)))
  (define x 0)
  (provide/contract [inc-x! (-> void?)]
                    [get-x (-> integer?)])

Moral: This is a bug we hope to address in a future release.